Can anyone help me out please?

E

ElDubya

Well-Known Member
Hi all,

I have tried editing this file half a dozen times and broken the script every time. I need to merge these two sections together so I can keep my gold coin and plot management working but add origins building stuff.

Code: 
_object_inventory = {
    private["_inventory","_previous","_key","_updateGear"];
    _updateGear = false;
    if((typeOf _object) in DZE_Origins_Buildings) then {
        _state = _object getVariable ["CanBeUpdated",false];
        if(_state) then {
            _updateGear = true;
            _object setVariable ["WeaponCargo", getWeaponCargo _object,true];
            _object setVariable ["MagazineCargo", getMagazineCargo  _object,true];
            _object setVariable ["BackpackCargo", getBackpackCargo  _object,true];
            _inventory = [
                _object getVariable["WeaponCargo",[]],
                _object getVariable["MagazineCargo",[]],
                _object getVariable["BackpackCargo",[]]
            ];
        };
    } else {
        _updateGear = true;
        _inventory = [
            getWeaponCargo _object,
            getMagazineCargo _object,
            getBackpackCargo _object
        ];
    };
    if(_updateGear) then {
        _previous = str(_object getVariable["lastInventory",[]]);
        if (str(_inventory) != _previous) then {
            _object setVariable["lastInventory",_inventory];
            if (_objectID == "0") then {
                _key = format["CHILD:309:%1:%2:",_uid,_inventory];
            } else {
                _key = format["CHILD:303:%1:%2:",_objectID,_inventory];
            };
            //diag_log ("HIVE: WRITE: "+ str(_key));
            _key call server_hiveWrite;
        };
    };
};

and

Code: 
_object_inventory = {
    private["_inventory","_previous","_key"];
        if (typeOf (_object) == "Plastic_Pole_EP1_DZ") then{
    _inventory = _object getVariable ["plotfriends", []]; //We're replacing the inventory with UIDs for this item
} else {
        _inventory = [
            getWeaponCargo _object,
            getMagazineCargo _object,
            getBackpackCargo _object
            /*ZSC*/
            , _object getVariable["bankMoney",0]
            /*ZSC*/
        ];
};
        _previous = str(_object getVariable["lastInventory",[]]);
        if (str(_inventory) != _previous) then {
            _object setVariable["lastInventory",_inventory];
            if (_objectID == "0") then {
                _key = format["CHILD:309:%1:%2:",_uid,_inventory];
            } else {
                _key = format["CHILD:303:%1:%2:",_objectID,_inventory];
            };
            //diag_log ("HIVE: WRITE: "+ str(_key));
            _key call server_hiveWrite;
        };
};

together and can't for the life of me figure out how. Any help would be GREATLY appreciated.
 
give this one a shot :) i merged the 2 into one, it should work fine (you need to test it)

Code: 
_object_inventory = {
    private["_inventory","_previous","_key","_updateGear"];
    _updateGear = false;
  
    if((typeOf _object) in DZE_Origins_Buildings) then {
        _state = _object getVariable ["CanBeUpdated",false];
        if(_state) then {
            _updateGear = true;
            _object setVariable ["WeaponCargo", getWeaponCargo _object,true];
            _object setVariable ["MagazineCargo", getMagazineCargo  _object,true];
            _object setVariable ["BackpackCargo", getBackpackCargo  _object,true];
            _inventory = [
                _object getVariable["WeaponCargo",[]],
                _object getVariable["MagazineCargo",[]],
                _object getVariable["BackpackCargo",[]]
            ];
        };
    } else {
        if (typeOf (_object) == "Plastic_Pole_EP1_DZ") then{
            _inventory = _object getVariable ["plotfriends", []]; //We're replacing the inventory with UIDs for this item
        }else{
            _updateGear = true;
            _inventory = [
                getWeaponCargo _object,
                getMagazineCargo _object,
                getBackpackCargo _object,
                _object getVariable["bankMoney",0]
            ];
        };
    };
    if(_updateGear) then {
        _previous = str(_object getVariable["lastInventory",[]]);
        if (str(_inventory) != _previous) then {
            _object setVariable["lastInventory",_inventory];
            if (_objectID == "0") then {
                _key = format["CHILD:309:%1:%2:",_uid,_inventory];
            } else {
                _key = format["CHILD:303:%1:%2:",_objectID,_inventory];
            };
            //diag_log ("HIVE: WRITE: "+ str(_key));
            _key call server_hiveWrite;
        };
    };
};
 
Cheers FallingSheep, I should have updated this thread. SchwEde has been helping me out with this over on epoch forums. He is being very kind with his time actually, so it's all under control. I do thank you for taking the time to merge it for me though mate, appreciate it :)
 
You must log in or register to reply here.
Back
Top