Tried that but it doesn't work. If you do it that way then it apparently lacks some sort of definition as to what the skin actually is, because it returns an error saying that you don't have enough room to add skin _________, despite the fact that there are multiple inventory slots free. There are no errors in the RPT either on server or client.
[Help/Discussion] Zabns Take Clothes
- Thread starter Zabn
- Start date
Tried that but it doesn't work. If you do it that way then it apparently lacks some sort of definition as to what the skin actually is, because it returns an error saying that you don't have enough room to add skin _________, despite the fact that there are multiple inventory slots free. There are no errors in the RPT either on server or client.
Inkko
Valued Member!
Since most of the skins in overpoch don't have actual skin parcels (like what you have in your inventory to click on and wear), just an assumption, you would have to do a playermorph to wear the skin instead of getting the skin added into your inventory.
ShootingBlanks
OpenDayZ Guru!
Well maybe thats why my edited takeclothes script has worked so well for all these ages. I removed all the crap and just switch the skins, works on any skin, at any time, anywhere
this is the ENTIRE script right here. This is all you need.
the fn_selfactions.sqf code .. I believe this is the default code
This doesn't put YOUR skin on the dead body or switch the gear. It just takes the skin and puts it on you. I never had anyone mention anything about it being different, nobody noticed.
Just reviewing the script and I see that we could limit the clothes to be taken by only one person by adding
at the end of the 'take clothes' script.
this is the ENTIRE script right here. This is all you need.
Code:
private["_skin","_body"];
_body = _this select 3;
player removeAction s_player_clothes;
s_player_clothes = -1;
_skin = (typeOf _body);
[dayz_playerUID, dayz_characterID, _skin] spawn player_humanityMorph;the fn_selfactions.sqf code .. I believe this is the default code
Code:
//CLOTHES*************************************************************
_clothesTaken = cursorTarget getVariable["clothesTaken",false];
// Take clothes by Zabn @ BalotaBuddies.net
if (_isMan and !_isAlive and !_isZombie and !_isAnimal and !_clothesTaken) then {
if (s_player_clothes < 0) then {
s_player_clothes = player addAction [("<t color='#0096ff'>")+("Take Clothes")+("</t>"), "scripts\player_takeClothes.sqf",cursorTarget, -10, false, true, "",""];
};
} else {
player removeAction s_player_clothes;
s_player_clothes = -1;
};
//**************************************************************This doesn't put YOUR skin on the dead body or switch the gear. It just takes the skin and puts it on you. I never had anyone mention anything about it being different, nobody noticed.
Just reviewing the script and I see that we could limit the clothes to be taken by only one person by adding
Code:
cursorTarget setVariable["clothesTaken",true];
Last edited:
Inkko
Valued Member!
I posted a script I haven't tested yet a page back that integrates the playermorph into the script. If it can't give you the skin into your inventory it will playermorph you to the skin and give you the skin of what you're wearing if it can.
ShootingBlanks
OpenDayZ Guru!
Inkkos above mentioned script looks great.
I am reposting Inkkos edited script as its probably a good fix for unsupported skins.
I am reposting Inkkos edited script as its probably a good fix for unsupported skins.
Code:
// By Zabn 2014
//edited by Inkko to add unsupported skins
private["_isEpoch","_itemNew","_female","_pitemNew","_pokSkin","_pskin","_pitemNewName","_result2","","_onLadder","_skin","_body","_okSkin","_clothesTaken","_itemNewName","_result","_animState","_takeClothesUsageTime","_started","_finished","_takeClothesUseTime"];
if (!isNil "DZE_ActionInProgress") then { // check if this is dayz epoch
if (DZE_ActionInProgress) exitWith {}; // Do not allow if any script is running.
};
_body = _this select 3;
_onLadder = (getNumber (configFile >> "CfgMovesMaleSdr" >> "States" >> (animationState player) >> "onLadder")) == 1;
if (_onLadder) exitWith {cutText ["You can't perform this action while on a ladder!" , "PLAIN DOWN"]};
if (vehicle player != player) exitWith {cutText ["You may not take clothes while in a vehicle", "PLAIN DOWN"]};
player removeAction s_player_clothes;
s_player_clothes = -1;
_skin = (typeOf _body);
_pskin = (typeof player);
_itemNew = _skin;
_pitemNew = _pskin;
switch (_itemNew) do {
case "Survivor3_DZ": {
_itemNew = "Survivor2_DZ";
};
case "Bandit1_DZ": {
_itemNew = "Survivor2_DZ";
};
};
_female = if (_skin in ["SurvivorW2_DZ","BanditW1_DZ"]) then {_regskin = false;} else {_regskin = true;};
_itemNew = "Skin_" + _itemNew;
_pitemNew = "Skin_" + _pitemNew;
_okSkin = isClass (configFile >> "CfgMagazines" >> _itemNew);
_pokSkin = isClass (configFile >> "CfgMagazines" >> _pitemNew);
_takeClothesUseTime = 6;
r_interrupt = false;
r_doLoop = true;
_takeClothesUsageTime = time;
_animState = animationState player;
_started = false;
_finished = false;
if(_okSkin || _female) then {
_clothesTaken = _body getVariable["clothesTaken",false];
if(!_clothesTaken) then {
while {r_doLoop} do {
private ["_isMedic"];
_clothesTaken = _body getVariable["clothesTaken",false];
_animState = animationState player;
_isMedic = ["medic",_animState] call fnc_inString;
if(_clothesTaken) then {
r_doLoop = false;
};
if (_isMedic) then {
_started = true;
};
if(!_isMedic && !r_interrupt && (time - _takeClothesUsageTime) < _takeClothesUseTime) then {
player playActionNow "Medic";
_isMedic = true;
};
if (_started && !_isMedic && (time - _takeClothesUsageTime) > _takeClothesUseTime) then {
r_doLoop = false;
_finished = true;
};
if (r_interrupt) then {
r_doLoop = false;
};
sleep 0.1;
};
r_doLoop = false;
if(_finished) then {
if (_okSkin) then {
_itemNewName = getText (configFile >> "CfgMagazines" >> _itemNew >> "displayName");
_result = [player,_itemNew] call BIS_fnc_invAdd;
if (_result) then {
_body setVariable["clothesTaken",true,true];
cutText [format["One %1 has been added to your inventory!",_itemNewName], "PLAIN DOWN"];
} else {
cutText [format["You didn't have enough room to store a %1 :(",_itemNewName], "PLAIN DOWN"];
};
} else {
if (_pokSkin) then {
_pitemNewName = getText (configFile >> "CfgMagazines" >> _pitemNew >> "displayName");
_result2 = [player,_pitemNew] call BIS_fnc_invAdd;
if (_result2) then {
cutText [format["You have packed your %1 up and decided to try on your new clothes instead!",_pitemNewName], "PLAIN DOWN"];
sleep 0.5;
_body setVariable["clothesTaken",true,true];
// maybe add something that changes model of body to regular survivor so players don't try to multiple uses?
[dayz_playerUID,dayz_characterID,_skin] spawn player_humanityMorph;
} else {
cutText [format["You lost your %1 you were wearing, but you atleast put on your new clothes!",_pitemNewName], "PLAIN DOWN"];
sleep 0.5;
_body setVariable["clothesTaken",true,true];
// maybe add something that changes model of body to regular survivor so players don't try to multiple uses?
[dayz_playerUID,dayz_characterID,_skin] spawn player_humanityMorph;
};
};
};
} else {
if(_clothesTaken) then {
player switchMove "";
player playActionNow "stop";
cutText ["This Skin has already been taken!", "PLAIN DOWN"];
} else {
r_interrupt = false;
player switchMove "";
player playActionNow "stop";
cutText [format["You have interrupted taking clothes!"], "PLAIN DOWN"]; //display text at bottom center of screen on interrupt
};
};
} else {
cutText ["This Skin has already been taken!", "PLAIN DOWN"];
};
} else {
cutText [format["Currently %1 is not supported by the steal skin script.",_skin], "PLAIN DOWN"];
};Inkko
Valued Member!
Just want to reiterate that I haven't tested the script... but it should work perfectly fine and it should work with any mod. I just have it not supporting female skins due to me personally running vanilla dayz and the additional female skins available are not fully functional.
This does not work at all. I get this error in my client RPT when running it:
Code:
Error in expression <s\addons\player_takeClothes_V2.sqf"
private["_isEpoch","_itemNew","_female",>
Error position: <private["_isEpoch","_itemNew","_female",>
Error typeof: Local variable in global space
File mpmissions\__CUR_MP.Chernarus\addons\player_takeClothes_V2.sqf, line 5ShootingBlanks
OpenDayZ Guru!
"_result2","","_onLadder"
could this be the problem on line 5?
could this be the problem on line 5?
You were right. I fixed that fine. But now there's this:
Code:
Error in expression <othes;
s_player_clothes = -1;
_skin = (typeOf _body);
_pskin = (typeof player);>
Error position: <typeOf _body);
_pskin = (typeof player);>
Error typeof: Type Array, expected Object
File mpmissions\__CUR_MP.Chernarus\addons\player_takeClothes_V2.sqf, line 20Inkko
Valued Member!
I'll be able to test out the script and get it working, should have it done later tonight.
Inkko
Valued Member!
Here is an updated version that is working on 1.8.2 for me.
Code:
// By Zabn 2014
private["_itemNew","_isFemale","_PlayeritemNew","_PlayerokSkin","_Playerskin","_PlayeritemNewName","_result2","_onLadder","_skin","_body","_okSkin","_clothesTaken","_itemNewName","_result","_animState","_takeClothesUsageTime","_started","_finished","_takeClothesUseTime"];
if (!isNil "DZE_ActionInProgress") then { // check if this is dayz epoch
if (DZE_ActionInProgress) exitWith {}; // Do not allow if any script is running.
};
_body = _this select 3;
_onLadder = (getNumber (configFile >> "CfgMovesMaleSdr" >> "States" >> (animationState player) >> "onLadder")) == 1;
if (_onLadder) exitWith {cutText ["You can't perform this action while on a ladder!" , "PLAIN DOWN"]};
if (vehicle player != player) exitWith {cutText ["You may not take clothes while in a vehicle", "PLAIN DOWN"]};
player removeAction s_player_clothes;
s_player_clothes = -1;
_skin = (typeOf _body);
// get skin of player
_Playerskin = (typeOf player);
_itemNew = _skin;
//
_PlayeritemNew = _Playerskin;
// lets exit script if player is already wearing the skin he is trying to steal...
if (_skin == _Playerskin) exitwith {cutText [format["You are already wearing this skin!"], "PLAIN DOWN"];};
switch (_itemNew) do {
case "Survivor3_DZ": {
_itemNew = "Survivor2_DZ";
};
case "Bandit1_DZ": {
_itemNew = "Survivor2_DZ";
};
};
// switching humanity models that have no parcel for giving back parcels on non supported skins,
// add aditional above and below if additional skin parcels exist.
switch (_PlayeritemNew) do {
case "Survivor3_DZ": {
_PlayeritemNew = "Survivor2_DZ";
};
case "Bandit1_DZ": {
_PlayeritemNew = "Survivor2_DZ";
};
};
// female check on player
_isFemale = ((_Playerskin == "SurvivorW2_DZ") || (_Playerskin == "BanditW1_DZ"));
_itemNew = "Skin_" + _itemNew;
// Adding parcel name value
_PlayeritemNew = "Skin_" + _PlayeritemNew;
_okSkin = isClass (configFile >> "CfgMagazines" >> _itemNew);
// checking new name against configs
_PlayerokSkin = isClass (configFile >> "CfgMagazines" >> _PlayeritemNew);
_takeClothesUseTime = 6;
r_interrupt = false;
r_doLoop = true;
_takeClothesUsageTime = time;
_animState = animationState player;
_started = false;
_finished = false;
// if body skin has parcel, or player is not a female.
if((_okSkin) || (!_isFemale)) then {
_clothesTaken = _body getVariable["clothesTaken",false];
if(!_clothesTaken) then {
while {r_doLoop} do {
private ["_isMedic"];
_clothesTaken = _body getVariable["clothesTaken",false];
_animState = animationState player;
_isMedic = ["medic",_animState] call fnc_inString;
if(_clothesTaken) then {
r_doLoop = false;
};
if (_isMedic) then {
_started = true;
};
if(!_isMedic && !r_interrupt && (time - _takeClothesUsageTime) < _takeClothesUseTime) then {
player playActionNow "Medic";
_isMedic = true;
};
if (_started && !_isMedic && (time - _takeClothesUsageTime) > _takeClothesUseTime) then {
r_doLoop = false;
_finished = true;
};
if (r_interrupt) then {
r_doLoop = false;
};
sleep 0.1;
};
r_doLoop = false;
if(_finished) then {
// If skin has parcel. Add parcel to body.
if (_okSkin) then {
_itemNewName = getText (configFile >> "CfgMagazines" >> _itemNew >> "displayName");
_result = [player,_itemNew] call BIS_fnc_invAdd;
if (_result) then {
_body setVariable["clothesTaken",true,true];
cutText [format["One %1 has been added to your inventory!",_itemNewName], "PLAIN DOWN"];
} else {
};
} else {
// If no parcel can be obtained from body, humanitymorph to directly wear skin.
// Checking if current player skin can be moved to inventory and player not female.
if (_PlayerokSkin && !_isFemale) then {
_PlayeritemNewName = getText (configFile >> "CfgMagazines" >> _PlayeritemNew >> "displayName");
_result2 = [player,_PlayeritemNew] call BIS_fnc_invAdd;
// If parcel can be made from currently worn skin, added to inventory and humanitymorph to new skin.
if (_result2) then {
cutText [format["You have packed your %1 up and decided to try on your new clothes instead!",_PlayeritemNewName], "PLAIN DOWN"];
sleep 0.5;
_body setVariable["clothesTaken",true,true];
// maybe add something that changes model of body to regular survivor so players don't try multiple uses?
[dayz_playerUID,dayz_characterID,_skin] spawn player_humanityMorph;
} else {
cutText [format["You didn't have enough room to store a %1 :(",_itemNewName], "PLAIN DOWN"];
};
} else {
// If parcel from players worn skin cannot be found, humanity morph and lose skin player was wearing.
cutText [format["You lost your %1 you were wearing, but you atleast put on your new clothes!",_Playerskin], "PLAIN DOWN"];
sleep 0.5;
_body setVariable["clothesTaken",true,true];
// maybe add something that changes model of body to what player was wearing?
[dayz_playerUID,dayz_characterID,_skin] spawn player_humanityMorph;
};
};
} else {
if(_clothesTaken) then {
player switchMove "";
player playActionNow "stop";
cutText ["This Skin has already been taken!", "PLAIN DOWN"];
} else {
r_interrupt = false;
player switchMove "";
player playActionNow "stop";
cutText [format["You have interrupted taking clothes!"], "PLAIN DOWN"]; //display text at bottom center of screen on interrupt
};
};
} else {
cutText ["This Skin has already been taken!", "PLAIN DOWN"];
};
} else {
cutText [format["Currently %1 is not supported by the steal skin script.",_skin], "PLAIN DOWN"];
};
Last edited:
Inkko
Valued Member!
I just did a quick update to is since I forgot to remove something from the private array. The post was updated, pretty much every script that was working in 1.8.0.3 is working in 1.8.2. Only thing I've had issues with is halo spawns and my handcuff script.
Inkko
Valued Member!
If you're wanting the action not to show up for certain skins then you could try this change to fn_selfactions:
Code:
// Take clothes by Zabn
if (_isMan and !_isAlive and !_isZombie and !_clothesTaken and !((typeOf cursorTarget) in ["FR_AC"])) then {
if (s_player_clothes < 0) then {
s_player_clothes = player addAction [("<t color='#0096ff'>")+("Take Clothes")+("</t>"), "Scripts\player_takeClothes_v2.sqf",_cursorTarget, -10, false, true, "",""];
};
} else {
player removeAction s_player_clothes;
s_player_clothes = -1;
};I believe it would make the option not show up if the body is whatever skin you check for.
Alternatively you could make an exitwith statement in the take clothes file to exit if the model is in an array.
hey inkko ... thx for your help.
i tried your code, but it still not work
the Support message is away, but the Option is given.... u ve got another idea perhapes?
is it anyway possible to disable the Option for one Special Skin?
sry im not a coder .. so what u mean with Exit Statement?
i tried your code, but it still not work
the Support message is away, but the Option is given.... u ve got another idea perhapes?
is it anyway possible to disable the Option for one Special Skin?
sry im not a coder .. so what u mean with Exit Statement?
Inkko
Valued Member!
You could always try out my code above which would enable all skins, you could add an exitwith inside the fn_selfaction or inside the take clothes script. With the exitwith inside the take clothes script would be kinda pointless tho.hey inkko ... thx for your help.
i tried your code, but it still not work
the Support message is away, but the Option is given.... u ve got another idea perhapes?
is it anyway possible to disable the Option for one Special Skin?
sry im not a coder .. so what u mean with Exit Statement?
Maybe something like this:
Code:
// Take clothes by Zabn
if (_isMan and !_isAlive and !_isZombie and !_clothesTaken) then {
if ((typeOf _cursorTarget) in ["FR_AC"]) exitwith {player removeAction s_player_clothes;s_player_clothes = -1;};
if (s_player_clothes < 0) then {
s_player_clothes = player addAction [("<t color='#0096ff'>")+("Take Clothes")+("</t>"), "Scripts\player_takeClothes_v2.sqf",_cursorTarget, -10, false, true, "",""];
};
} else {
player removeAction s_player_clothes;
s_player_clothes = -1;
};Still getting a client error in Overpoch
Code:
Error in expression <othes;
s_player_clothes = -1;
_skin = (typeOf _body);
_Playerskin = (typeOf pl>
Error position: <typeOf _body);
_Playerskin = (typeOf pl>
Error typeof: Type Array, expected Object
File mpmissions\__CUR_MP.Chernarus\addons\player_takeClothes_V2.sqf, line 17Inkko
Valued Member!
What does your fn_selfactions look like for the take clothes script portion?