Working halo jump script 1.8.0.3

Merg

Well-Known Member
So does anyone have a working halo jump script for 1.8.0.3? Mine just does not run...
 
http://opendayz.net/threads/working-halo-jump-new-re-spawn-only.12113/ - activities same as in 1.7.7.1
dayz_1.Chernarus/init.sqf
Code:
execVM "Halo_Jump\halojumpinclude.sqf";
dayz_1.Chernarus/Halo_Jump/halojumpinclude.sqf
Code:
bis_fnc_halo = compile preprocessFileLineNumbers "Halo_Jump\fn_halo.sqf";
if (!isDedicated) then {
    [] spawn {
        while {true} do
        {
            if ( (cursorTarget isKindOf "Air") and (getDammage cursorTarget < 0.95) and (!isNull player) ) then {
              _vehicle = cursorTarget;
              _HALO_CARGO_ActionAdded = _vehicle getVariable["HALO_CARGO_ActionAdded",false];
        
              if( !_HALO_CARGO_ActionAdded ) then {
                _vehicle setVariable ["HALO_CARGO_ActionAdded", true];
                // HALO Jump
                s_halo_action = _vehicle addAction [("<t color=""#FF9800"">" + ("HALO Jump") + "</t>"),"Halo_Jump\halojumpinit.sqf",[],2,false,true,"","(getPosATL player select 2) > 10"];
              };
            };
            sleep 1;
        };
    };
};
if (!isDedicated) then {
    [] spawn {
        waitUntil { !isNil ("dayzLoginRecord") and
!(player getVariable ["humanity",0] > 5000 and
typeOf player == "Survivor2_DZ") and
!(player getVariable ["humanity",0] < -2000 and
(typeOf player == "Survivor2_DZ" or
typeOf player == "SurvivorW2_DZ") ) and
!(player getVariable ["humanity",0] > 0 and
(typeOf player == "Bandit1_DZ" or
typeOf player == "BanditW1_DZ") )
};
        if (dayzPlayerLogin2 select 2) then
        {
            [player, 1000] spawn bis_fnc_halo;
   // _nul = [] execVM "Halo_Jump\altimeter_gui.sqf";
        };
    };
};
dayz_1.Chernarus/Halo_Jump/halojumpinit.sqf
Code:
player spawn bis_fnc_halo;
player action [ "eject", vehicle player];
 
dayz_1.Chernarus/Halo_Jump/fn_halo.sqf
part1
Code:
scriptName "modules_e\Functions\objects\fn_HALO.sqf";
/*
    File: fn_HALO.sqf
    Author: Karel Moricky

    Description:
    High Altitude Low Opening

    Parameter(s):
    _this:    ARRAY    - starts HALO jump directly
        OBJECT    - waits until unit in array is out of vehicle

    Returns:
    Nothing
*/

sleep 0.01;

//--- HALO -------------------------------------------------------------------------------------------------------------------------------------
if (typename _this == typename objnull) then {

    _unit = _this;

    //--- Eject!
    waituntil {(vehicle _unit) iskindof "ParachuteBase" || !isnil {_unit getvariable "bis_fnc_halo_now"}};
    if (!local _unit) exitwith {};

    //--- Delete parachute
    _parachute = vehicle _unit;
    if (_parachute != _unit) then {
        deletevehicle _parachute;
    };

    //--- Init
    _dir = ([[0,0,0],velocity _unit] call bis_fnc_dirto);
    _unit setdir _dir;
    _unit switchmove "HaloFreeFall_non";

    //--- Key controls
    if (_unit == player) then {
        //--- PLAYER ------------------------------------------------

        _brightness = 0.99;
        _pos = position player;
        _parray = [
        /* 00 */        ["\Ca\Data\ParticleEffects\Universal\Universal", 16, 12, 13, 0],
        /* 01 */        "",
        /* 02 */        "Billboard",
        /* 03 */        1,
        /* 04 */        3,
        /* 05 */        [0,0,-200],
        /* 06 */        wind,
        /* 07 */        0,
        /* 08 */        1.275,
        /* 09 */        1,
        /* 10 */        0,
        /* 11 */        [100],
        /* 12 */        [
                            [_brightness,_brightness,_brightness,0],
                            [_brightness,_brightness,_brightness,0.01],
                            [_brightness,_brightness,_brightness,0.10],
                            [_brightness,_brightness,_brightness,0]
                        ],
        /* 13 */        [1000],
        /* 14 */        0,
        /* 15 */        0,
        /* 16 */        "",
        /* 17 */        "",
        /* 18 */        player
        ];
        bis_fnc_halo_clouds = "#particlesource" createVehicleLocal _pos; 
        bis_fnc_halo_clouds setParticleParams _parray;
        bis_fnc_halo_clouds setParticleRandom [0, [100, 100, 0], [0, 0, 0], 0, 0, [0, 0, 0, 0], 0, 1];
        bis_fnc_halo_clouds setParticleCircle [00, [00, 00, 00]];
        bis_fnc_halo_clouds setDropInterval (0.4 - (0.3 * overcast));


        //--- Effects
        bis_fnc_halo_ppRadialBlur = ppeffectcreate ["RadialBlur",464];
        bis_fnc_halo_ppRadialBlur ppEffectAdjust [0.01,0.01,0.3,0.3];
        bis_fnc_halo_ppRadialBlur ppEffectCommit 0.01;
        bis_fnc_halo_ppRadialBlur ppEffectEnable true ;
        bis_fnc_halo_soundLoop = time;
        playsound "BIS_HALO_Flapping";

        bis_fnc_halo_action = _unit addaction [localize "STR_HALO_OPEN_CHUTE","Halo_Jump\fn_halo.sqf",[],1,true,true,"Eject"];

        bis_fnc_halo_keydown = {
            _key = _this select 1;

            //--- Forward
            //if (_key in (actionkeys 'HeliForward')) then {
            if (_key in (actionkeys 'MoveForward')) then {
                if (bis_fnc_halo_vel < +bis_fnc_halo_velLimit) then {bis_fnc_halo_vel = bis_fnc_halo_vel + bis_fnc_halo_velAdd};
            };

            //--- Backward
            //if (_key in (actionkeys 'HeliBack')) then {
            if (_key in (actionkeys 'MoveBack')) then {
                if (bis_fnc_halo_vel > -bis_fnc_halo_velLimit) then {bis_fnc_halo_vel = bis_fnc_halo_vel - bis_fnc_halo_velAdd};
            };

            //--- Left
            //if (_key in (actionkeys 'HeliCyclicLeft')) then {
            if (_key in (actionkeys 'TurnLeft')) then {
                if (bis_fnc_halo_dir > -bis_fnc_halo_dirLimit) then {bis_fnc_halo_dir = bis_fnc_halo_dir - bis_fnc_halo_dirAdd};
            };

            //--- Right
            //if (_key in (actionkeys 'HeliCyclicRight')) then {
            if (_key in (actionkeys 'TurnRight')) then {
                if (bis_fnc_halo_dir < +bis_fnc_halo_dirLimit) then {bis_fnc_halo_dir = bis_fnc_halo_dir + bis_fnc_halo_dirAdd};
            };
        };
        bis_fnc_halo_keydown_eh = (finddisplay 46) displayaddeventhandler ["keydown","_this call bis_fnc_halo_keydown;"];

        //--- Loop
        bis_fnc_halo_vel = 0;
        bis_fnc_halo_velLimit = 0.2;
        bis_fnc_halo_velAdd = 0.03;
        bis_fnc_halo_dir = 0;
        bis_fnc_halo_dirLimit = 1;
        bis_fnc_halo_dirAdd = 0.06;

        [] spawn {
            _time = time - 0.1;
            while {alive player && vehicle player == player && isnil {player getvariable "bis_fnc_halo_terminate"}} do {

                //--- FPS counter
                _fpsCoef = ((time - _time) * 60) / acctime; //Script is optimized for 60 FPS
                _time = time;

                bis_fnc_halo_velLimit = 0.2 * _fpsCoef;
                bis_fnc_halo_velAdd = 0.03 * _fpsCoef;
                bis_fnc_halo_dirLimit = 1 * _fpsCoef;
                bis_fnc_halo_dirAdd = 0.06 * _fpsCoef;

                //--- Dir
                bis_fnc_halo_dir = bis_fnc_halo_dir * 0.98;
                _dir = direction player + bis_fnc_halo_dir;
                player setdir _dir;

                //--- Velocity
                _vel = velocity player;
                bis_fnc_halo_vel = bis_fnc_halo_vel * 0.96;
                player setvelocity [
                    (_vel select 0) + (sin _dir * bis_fnc_halo_vel),
                    (_vel select 1) + (cos _dir * bis_fnc_halo_vel),
                    (_vel select 2)
                ];

                //--- Animation system
                _anim = "HaloFreeFall_non";
                _v = bis_fnc_halo_vel;
                _h = bis_fnc_halo_dir;

                _vLimit = 0.1;
                _hLimit = 0.3;
                if ((abs _v) > _vLimit || (abs _h) > _hLimit) then {
                    _vAnim = "";
                    if (_v > +_vLimit) then {_vAnim = "F"};
                    if (_v < -_vLimit) then {_vAnim = "B"};
                    _hAnim = "";
                    if (_h > +_hLimit) then {_hAnim = "R"};
                    if (_h < -_hLimit) then {_hAnim = "L"};
                    _anim = "HaloFreeFall_" + _vAnim + _hAnim;
                };
 
dayz_1.Chernarus/Halo_Jump/fn_halo.sqf
part2
Code:
                player playmovenow _anim;
                //--- Sound
                if ((time - bis_fnc_halo_soundLoop) > 4.5) then {
                    playsound "BIS_HALO_Flapping";
                    bis_fnc_halo_soundLoop = time;
                };
                //--- Effects
                bis_fnc_halo_ppRadialBlur ppEffectAdjust [0.02,0.02,0.3 - (bis_fnc_halo_vel/7)/_fpsCoef,0.3 - (bis_fnc_halo_vel/7)/_fpsCoef];
                bis_fnc_halo_ppRadialBlur ppEffectCommit 0.01;
                sleep 0.01;
            };
            //--- End
            player removeaction bis_fnc_halo_action;
            (finddisplay 46) displayremoveeventhandler ["keydown",bis_fnc_halo_keydown_eh];
            ppeffectdestroy bis_fnc_halo_ppRadialBlur;
            deletevehicle bis_fnc_halo_clouds;
            bis_fnc_halo_clouds = nil;
            bis_fnc_halo_vel = nil;
            bis_fnc_halo_velLimit = nil;
            bis_fnc_halo_velAdd = nil;
            bis_fnc_halo_dir = nil;
            bis_fnc_halo_dirLimit = nil;
            bis_fnc_halo_dirAdd = nil;
            bis_fnc_halo_action = nil;
            bis_fnc_halo_keydown = nil;
            bis_fnc_halo_keydown_eh = nil;
            if (!alive player) then {
                player switchmove "adthppnemstpsraswrfldnon_1";
                player setvelocity [0,0,0];
            };
        };
    } else {
        //--- AI ------------------------------------------------
        while {(position _unit select 2) > 100} do {
            _destination = expecteddestination _unit select 0;
            if (_destination distance [position _unit select 0,position _unit select 1,0] > 10) then {
                _vel = velocity _unit;
                _dirTo = [_unit,_destination] call bis_fnc_dirto;
                if (player distance _unit > 500) then {
                    _unit setdir _dirTo;
                };
                _unit setvelocity [
                    (_vel select 0) + (sin _dirTo * 0.2),
                    (_vel select 1) + (cos _dirTo * 0.2),
                    (_vel select 2)
                ];
            };
            sleep 0.01;
        };
        //--- Open
        [_unit] spawn bis_fnc_halo;
    };
};
//--- PARA -------------------------------------------------------------------------------------------------------------------------------------
if (typename _this == typename []) then {
    _unit = _this select 0;
    if (!local _unit) exitwith {};
    //--- Free fall
    if (count _this == 2) exitwith {
        _alt = _this select 1;
        _unit setpos [position _unit select 0,position _unit select 1,_alt];
        _unit setvariable ["bis_fnc_halo_now",true];
        _unit spawn bis_fnc_halo;
    };
    //-------------
    _para = "ParachuteWest" createVehicle position _unit;
    //_para = "BIS_Steerable_Parachute" createVehicle position _unit;
    _para setpos position _unit;
    _para setdir direction _unit;
    _vel = velocity _unit;
    _unit moveindriver _para;
    //_unit moveingunner _para;
    _para lock false;
    bis_fnc_halo_para_dirAbs = direction _para;
    //--- Key controls
    if (_unit == player) then {
        _para setvelocity [(_vel select 0),(_vel select 1),(_vel select 2)*1];
        bis_fnc_halo_DynamicBlur = ppeffectcreate ["DynamicBlur",464];
        bis_fnc_halo_DynamicBlur ppEffectEnable true;
        bis_fnc_halo_DynamicBlur ppEffectAdjust [8.0];
        bis_fnc_halo_DynamicBlur ppEffectCommit 0;
        bis_fnc_halo_DynamicBlur ppEffectAdjust [0.0];
        bis_fnc_halo_DynamicBlur ppEffectCommit 1;
        bis_fnc_halo_para_vel = 0;
        bis_fnc_halo_para_velLimit = 0.5;
        bis_fnc_halo_para_velAdd = 0.01;
        bis_fnc_halo_para_dir = 0;
        bis_fnc_halo_para_dirLimit = 1.5;
        bis_fnc_halo_para_dirAdd = 0.03;
        bis_fnc_halo_para_keydown = {
            _key = _this select 1;
            //--- Forward
            if (_key in (actionkeys 'MoveForward')) then {
                if (bis_fnc_halo_para_vel < +bis_fnc_halo_para_velLimit) then {bis_fnc_halo_para_vel = bis_fnc_halo_para_vel + bis_fnc_halo_para_velAdd};
            };
            //--- Backward
            if (_key in (actionkeys 'MoveBack')) then {
                if (bis_fnc_halo_para_vel > -bis_fnc_halo_para_velLimit*0) then {bis_fnc_halo_para_vel = bis_fnc_halo_para_vel - bis_fnc_halo_para_velAdd};
            };
            //--- Left
            if (_key in (actionkeys 'TurnLeft')) then {
                if (bis_fnc_halo_para_dir > -bis_fnc_halo_para_dirLimit) then {bis_fnc_halo_para_dir = bis_fnc_halo_para_dir - bis_fnc_halo_para_dirAdd};
            };
            //--- Right
            if (_key in (actionkeys 'TurnRight')) then {
                if (bis_fnc_halo_para_dir < +bis_fnc_halo_para_dirLimit) then {bis_fnc_halo_para_dir = bis_fnc_halo_para_dir + bis_fnc_halo_para_dirAdd};
            };
        };
        bis_fnc_halo_para_loop_time = time - 0.1;
        bis_fnc_halo_para_velZ = velocity _para select 2;
        bis_fnc_halo_para_loop = {
                if (!isnil {player getvariable "bis_fnc_halo_terminate"}) exitwith {};
                if (time == bis_fnc_halo_para_loop_time) exitwith {}; //--- FPS too high
                _para = vehicle player;
                //--- FPS counter
                _fpsCoef = ((time - bis_fnc_halo_para_loop_time) * 20) / acctime; //Script is optimized for 20 FPS
                bis_fnc_halo_para_loop_time = time;
                //_fpsCoef = _fpsCoef / 3;
                bis_fnc_halo_para_velLimit = 0.3 * _fpsCoef;
                bis_fnc_halo_para_velAdd = 0.002 * _fpsCoef;
                bis_fnc_halo_para_dirLimit = 1.5 * _fpsCoef;
                bis_fnc_halo_para_dirAdd = 0.03 * _fpsCoef;
                //--- Dir
                bis_fnc_halo_para_dir = bis_fnc_halo_para_dir * 0.98;
                bis_fnc_halo_para_dirAbs = bis_fnc_halo_para_dirAbs + bis_fnc_halo_para_dir;
                _para setdir bis_fnc_halo_para_dirAbs;
                _dir = direction _para;
                //--- Crash
                _velZ = velocity _para select 2;
                if ((_velZ - bis_fnc_halo_para_velZ) > 7 && (getposatl _para select 2) < 100) then {player setdamage 1;debuglog ["Log::::::::::::::",(_velZ - bis_fnc_halo_para_velZ)];};
                bis_fnc_halo_para_velZ = _velZ;
                //--- Pos
                _para setposasl [
                    (getposasl _para select 0) + (sin _dir * (0.1 + bis_fnc_halo_para_vel)),
                    (getposasl _para select 1) + (cos _dir * (0.1 + bis_fnc_halo_para_vel)),
                    (getposasl _para select 2) - 0.01 - 0.1 * abs bis_fnc_halo_para_vel
                ];
                [
                    _para,
                    (-bis_fnc_halo_para_vel * 75) + 0.5*(sin (time * 180)),
                    (+bis_fnc_halo_para_dir * 25) + 0.5*(cos (time * 180))
                ] call bis_fnc_setpitchbank;
        };
        bis_fnc_halo_para_mousemoving_eh = (finddisplay 46) displayaddeventhandler ["mousemoving","_this call bis_fnc_halo_para_loop;"];
        bis_fnc_halo_para_mouseholding_eh = (finddisplay 46) displayaddeventhandler ["mouseholding","_this call bis_fnc_halo_para_loop;"];
        sleep 4;
        ppeffectdestroy bis_fnc_halo_DynamicBlur;
        bis_fnc_halo_para_keydown_eh = (finddisplay 46) displayaddeventhandler ["keydown","_this call bis_fnc_halo_para_keydown;"];
        //--- End
        //waituntil {vehicle player == player};
        player setvariable ["bis_fnc_halo_terminate",nil];
        waituntil {(position vehicle player select 2) < 2 || !isnil {player getvariable "bis_fnc_halo_terminate"}};
        (finddisplay 46) displayremoveeventhandler ["keydown",bis_fnc_halo_para_keydown_eh];
        (finddisplay 46) displayremoveeventhandler ["mousemoving",bis_fnc_halo_para_mousemoving_eh];
        (finddisplay 46) displayremoveeventhandler ["mouseholding",bis_fnc_halo_para_mouseholding_eh];
        bis_fnc_halo_para_vel = nil;
        bis_fnc_halo_para_velLimit = nil;
        bis_fnc_halo_para_velAdd = nil;
        bis_fnc_halo_para_dir = nil;
        bis_fnc_halo_para_dirLimit = nil;
        bis_fnc_halo_para_dirAdd = nil;
        bis_fnc_halo_para_keydown = nil;
        bis_fnc_halo_para_loop = nil;
        bis_fnc_halo_para_keydown_eh = nil;
        bis_fnc_halo_para_mousemoving_eh = nil;
        bis_fnc_halo_para_mouseholding_eh = nil;
    };
};
 
TorturedChunk said:
Server Changes

1. dayz_server.pbo>>complie>>server_playerSetup.sqf

Find:
Code:
dayzPlayerLogin2 = [_worldspace,_state];

Change to:
Code:
dayzPlayerLogin2 = [_worldspace,_state,_randomSpot];


2. dayz_server.pbo>>system>>server_cleanup.fsm

Find:
Code:
      "Check for hackers" \n
      " {" \n
      "      if(vehicle _x != _x && !(vehicle _x in _safety) && (typeOf vehicle _x) != ""ParachuteWest"") then {" \n
      "      diag_log (""CLEANUP: KILLING A HACKER "" + (name _x) + "" "" + str(_x) + "" IN "" + (typeOf vehicle _x));" \n
      "          (vehicle _x) setDamage 1;" \n
      "          _x setDamage 1;" \n
      "    };" \n
      " } forEach allUnits;" \n

Change to (Comment Out):
Code:
 //    "Check for hackers" \n
      "// {" \n
      "//    if(vehicle _x != _x && !(vehicle _x in _safety) && (typeOf vehicle _x) != ""ParachuteWest"") then {" \n
      "//      diag_log (""CLEANUP: KILLING A HACKER "" + (name _x) + "" "" + str(_x) + "" IN "" + (typeOf vehicle _x));" \n
      "//          (vehicle _x) setDamage 1;" \n
      "//          _x setDamage 1;" \n
      "//    };" \n
      "// } forEach allUnits;" \n
3. dayz_server.pbo>>compile>>server_updateObject.sqf

Find:
Code:
if (!_parachuteWest) then {
    if (_objectID == "0" && _uid == "0") then
    {
        _object_position = getPosATL _object;
            diag_log(format["Deleting object %1 with invalid ID at pos [%2,%3,%4]",
            typeOf _object,
            _object_position select 0,
            _object_position select 1,
            _object_position select 2]);
            _isNotOk = true;
    };
};


Change to (Comment Out):
Code:
/*
if (!_parachuteWest) then {
    if (_objectID == "0" && _uid == "0") then
    {
        _object_position = getPosATL _object;
            diag_log(format["Deleting object %1 with invalid ID at pos [%2,%3,%4]",
            typeOf _object,
            _object_position select 0,
            _object_position select 1,
            _object_position select 2]);
            _isNotOk = true;
    };
};
*/
 
Try it!
dayz_1.Chernarus/init.sqf
Code:
execVM "Halo_Jump\halospawninclude_v2.sqf";
dayz_1.Chernarus/Halo_Jump/halospawninclude_v2.sqf
Code:
//HALO SPAWN SCRIPT

MC_BIS_halo_spawn = compile preprocessFileLineNumbers "Halo_Jump\halospawninit_v2.sqf";

private["_mkr"];

_mkr = "spawn" + str(round(random 4));

if (!isDedicated) then {
    [] spawn {
        waitUntil { !isNil ("dayz_animalCheck") and
!(player getVariable ["humanity",0] > 5000 and
typeOf player == "Survivor2_DZ") and
!(player getVariable ["humanity",0] < -2000 and
(typeOf player == "Survivor2_DZ" or
typeOf player == "SurvivorW2_DZ") ) and
!(player getVariable ["humanity",0] > 0 and
(typeOf player == "Bandit1_DZ" or
typeOf player == "BanditW1_DZ") )
    };

        if (dayzPlayerLogin2 select 2 && dayzPlayerLogin select 4) then
        {
            _pos = position player;
            _mkr setMarkerPos [_pos select 0, _pos select 1];
            player spawn MC_BIS_halo_spawn;
    _nul = [] execVM "Halo_Jump\altimeter_gui.sqf";
        };
    };
};
dayz_1.Chernarus/Halo_Jump/halospawninit_v2.sqf
Code:
if (!isDedicated) then {
    [player, 1000] execVM "Halo_Jump\fn_halo.sqf";
};
dayz_1.Chernarus/Halo_Jump/fn_halo.sqf
http://opendayz.net/threads/working-halo-jump-script-1-8-0-3.17868/#post-89915 - part 1

http://opendayz.net/threads/working-halo-jump-script-1-8-0-3.17868/#post-89916 - part 2
 
Halo Jump spawn on 1.8.0.3 not tested, Halo Jump Only working on 1.8.0.3!
1.7.7.1 but I worked it into bundles Halo Jump + Spawn....
 
I mean what I've tried so far is in the server_PlayerSetup.sqf in the server pbo There is no sections that says "
dayzPlayerLogin2". The name of it has been changed to "PVCDZ_plr_Login2". So i've tried to change the line in halojumpinit.sqf to the new one but it still does not work.
 
Also, if running antihacks that look at _dayzactions, players wont be able to pull their parachute. You will need to add the following to the array in _dayzactions in the antihack code:
Code:
bis_fnc_halo_action
here add line to AH?
 
Ok i got it working, i'll paste my code here. Thanks for your help Shark-kun.

Add this to the bottom of your init.sqf in your mission file:
Code:
//--------------------HALO JUMP DAYZ 1.8.0.3-----------------------------------
MC_BIS_halo_spawn = compile preprocessFileLineNumbers "halo\haloInit.sqf";
private["_mkr"];
_mkr = "spawn" + str(round(random 4));
if (!isDedicated) then {
    [] spawn {
         waitUntil { !isNil ("dayz_animalCheck") and
!(player getVariable ["humanity",0] > 5000 and
typeOf player == "Survivor2_DZ") and
!(player getVariable ["humanity",0] < -2000 and
(typeOf player == "Survivor2_DZ" or
typeOf player == "SurvivorW2_DZ") ) and
!(player getVariable ["humanity",0] > 0 and
(typeOf player == "Bandit1_DZ" or
typeOf player == "BanditW1_DZ") )
};
        if (PVCDZ_plr_Login2 select 2) then
        {
            _pos = position player;
            _mkr setMarkerPos [_pos select 0, _pos select 1];
            player spawn MC_BIS_halo_spawn;
        };
    };
};
//--------------------HALO JUMP DAYZ 1.8.0.3-----------------------------------

create a folder cold halo in your mission root folder and add these files to it: https://www.dropbox.com/s/qs3zln55jusa8zt/halo.rar

Then in your server PBO, go to compile/server_playerSetup.sqf and search for
Code:
PVCDZ_plr_Login2

Replace that whole line with
Code:
PVCDZ_plr_Login2 = [_worldspace,_state,_randomSpot];

If you are using AH, remember to white list
Code:
bis_fnc_halo_action

In your init.sqf in your mission file, on the top you can find
Code:
dayz_antihack =
Make sure it is set to
0 (disabled).

Thats it, pack all you pbos and start you server
 
Last edited:
Back
Top