DayZ 1.8.0.3. Toggle on Debug causing in game issues. In Search of new way to toggle!

Vinyljunkie said:
No matter what I try I can't get the Debug Monitor to show in-game. Don't know what I am doing wrong.
I even copied ur code Russ but without success. I am missing something obvious perhaps?
Do i need to add code somewhere else aswell to "initialize" the debug?

No errors in RPT and server starts up just fine.
I have animated helicrashes, street lights and watermark logo added.

Thanks both of you for the help so far.
Click to expand...

Send me your compiles.sqf.. maybe its a typo or something.
 
seriously though, POST something that will help us help YOU. If you are running anything except epoch, then post your compiles.sqf file.
If you are running epoch, the post compiles.sqf and dayz_spaceinterrupt.sqf
 
Here is my compiles.sqf
http://pastebin.com/iVKfcGtu
The monitor is something i used but as a custom_monitor.sqf with an execute line in init.sqf and that worked except for the fact that players could not go into gear in vehicles and chopping wood became a full time job ;)

Thanks for being so helpful, really.

Edit: Running Vanilla DayZ Mod 1.8.0.3
 
ShootingBlanks said:
seriously though, POST something that will help us help YOU. If you are running anything except epoch, then post your compiles.sqf file.
If you are running epoch, the post compiles.sqf and dayz_spaceinterrupt.sqf
Click to expand...
Ive actually been trying to get a toggled debug monitor to work on my buddies epoch server but I can't find any good information on how to do it. Could you possibly enlighten me? I don't run epoch so I don't have much experience with it.
 
i am working on an epoch server at the very moment. I have the toggle function working but I got an error

F10 is not a permitted key on this server

Assumed infistar was blocking extraneous keys, but people are playing on the server now so i can't restart it and test.

Custom_monitor.sqf

Code: 
waitUntil {alive player};


    debugMonitor = true;
    while {debugMonitor} do {



    _kills =         player getVariable["zombieKills",0];
    _killsH =         player getVariable["humanKills",0];
    _killsB =         player getVariable["banditKills",0];
    _humanity =        player getVariable["humanity",0];
    _closestTown = (nearestLocations [getpos player,["namecitycapital","NameCity","NameVillage"],2000]) select 0;
    _town_name = text _closestTown;
    _Survivors = playersNumber west;
    _tL = (((21600 - time) / 60)-2);// 5 hours subtract the 2 minutes it took to restart last time ..
        _tL = round(_tL);
        if (_tL < 30) then { _tL = "Just a few";};

   
    hintSilent parseText format ["
    <img size='3' image='scripts\debug monitor\gd-logo.paa' align='center'/>
    <t size='1.15' font='Bitstream'align='center' color='#00FFFF'>Days Survived: %2</t><br/>
    <t size='0.95'font='Bitstream'align='left'>Nearest City:</t><t size='0.95'font='Bitstream'align='right'>%11</t><br/>
    <t size='0.95' font='Bitstream' align='left' color='#FFFFFF'>Murders: </t><t size='0.95' font='Bitstream' align='right'>%4</t><br/>
    <t size='0.95' font='Bitstream' align='left' color='#FFFFFF'>Bandits Killed: </t><t size='0.95' font='Bitstream' align='right'>%5</t><br/>
    <t size='0.95' font='Bitstream' align='left' color='#FFFFFF'>Zombies Killed: </t><t size='0.95' font='Bitstream' align='right'>%6</t><br/>
    <t size='0.95' font='Bitstream' align='left' color='#FFFFFF'>Humanity: </t><t size='0.95' font='Bitstream' align='right'>%7</t><br/>
    <t size='0.95' font='Bitstream' align='left' color='#DF0101'>Blood: </t><t size='0.95' font='Bitstream' align='right'>%8</t><br/>
    <t size='0.95' font='Bitstream' align='left' color='#FFFFFF'>Players Online:%3</t><t size='0.95' font='Bitstream' align='right'>FPS:%9</t><br/>
    <t size='1.15' font='Bitstream'align='center' color='#00FFFF'>Restart in %10 Minutes</t><br/>
   
   
    dayz_playerName,(dayz_Survived),_survivors,_killsH,_killsB,_kills,round _humanity,r_player_blood,(round diag_fps),_tL,_town_name"
    ];
sleep 1;
};

and in the dayz_spaceinterupt.sqf file
Code: 
if (_dikCode == 0x44 ) then {
    if (debugmonitor) then {
        debugmonitor = false;
        hintsilent "";
        }
    else {
        [] execVM "Scripts\Debug Monitor\custom_monitor.sqf";
        };

};


This is untested code essentially since the server I put it on prevents pressing the F10 key and as i already said, players prevent me from edits/restarts at the moment.
For some reason, I can not get an epoch server to run on my local test server.
 
I don't know what the rest of that gobbledegook you are running is, I only know about infistar because it INVARIABLY causes problems.
Try disabling all that stuff and see what happens. (I am sure I didn't have to tell you that though)
 
ShootingBlanks said:
I don't know what the rest of that gobbledegook you are running is, I only know about infistar because it INVARIABLY causes problems.
Try disabling all that stuff and see what happens. (I am sure I didn't have to tell you that though)
Click to expand...
if they are running a "bad key" check with infistar it will prevent you from pressing any of the function keys and some other keys as well and key combinations. I usually disable this feature because it causes more problems than it helps. Also, if you're using infiSTAR, f10 is the key you use to stop spectating a player, so that might cause conflictions as well.

You're well on your way to that rockstar status ;)

also, you should totally make a separate post for that menu you created..
 
DangerRuss said:
if they are running a "bad key" check with infistar it will prevent you from pressing any of the function keys and some other keys as well and key combinations. I usually disable this feature because it causes more problems than it helps. Also, if you're using infiSTAR, f10 is the key you use to stop spectating a player, so that might cause conflictions as well.

You're well on your way to that rockstar status ;)

also, you should totally make a separate post for that menu you created..
Click to expand...

Discovered that at the same time as you posted. I will change the F10 key to something else. Does Epoch use the Insert key for anything in the building?
 
ShootingBlanks said:
Discovered that at the same time as you posted. I will change the F10 key to something else. Does Epoch use the Insert key for anything in the building?
Click to expand...
No but it does have a built in debug monitor that is activated using the insert key. I have seen suggestions where you tell the server to stop looking for the default monitor and use yours instead

player_stats.sqf

http://opendayz.net/threads/custom-debug-prevents-building-in-epoch.15320/#post-83358

this broke my buddies server.. he was doing the code editing not me, so its possible he made a mistake.
 
Oh ,yeah, its in and working 100%. After the function keys thing, then I discovered that the cmd_menu option of inifistar needs to have my "help_dialog" whitelisted. Works perfectly now. I just have to insert some colorful text for it but I have a debug monitor and the help monitor working on an Epoch server I did for ghost division you can see it in action
play.g-division.com port 1234
I hosed up my image on the debug monitor and will be uploading a fixed on in a few minutes.
 
So you didnt edit the player_stats.sqf and just added the _dikCode to the dayz_spaceinterrupt.sqf? Ill give it a go.

I havent tested your newest help menu cause im a bit intimidated by it haha. I know practically nothing so ill eventually just try and follow your instructions as best I can.
 
Any special place the _dikCode should be called inside the dayz_spaceinterrupt.sqf? I tried setting it up but it just broke the debug monitor.
 
nope. anywhere is fine. And saying that putting the code in spaceinterrupt breaking the debug monitor is like saying that having a beers made your 300 lb girlfriend pregnant. One may lead to the other but its not directly responsible o_O. Take a look at this non-fat chick-impregnating version that works.
Code: 
private ["_dikCode","_handled","_primaryWeapon","_secondaryWeapon","_nearbyObjects","_nill","_shift","_ctrl","_alt","_dropPrimary","_dropSecondary","_iItem","_removed","_iPos","_radius","_item"];
_dikCode =     _this select 1;

_handled = false;

if (_dikCode in[0x02,0x03,0x04,0x58,0x57,0x44,0x43,0x42,0x41,0x40,0x3F,0x3E,0x3D,0x3C,0x3B,0x0B,0x0A,0x09,0x08,0x07,0x06,0x05]) then {
    _handled = true;
};

if ((_dikCode == 0x3E or _dikCode == 0x0F or _dikCode == 0xD3)) then {
    if(diag_tickTime - dayz_lastCheckBit > 10) then {
        dayz_lastCheckBit = diag_tickTime;
        call dayz_forceSave;
    };
    call dayz_EjectPlayer;
};

// esc
if (_dikCode == 0x01) then {
    DZE_cancelBuilding = true;
    call dayz_EjectPlayer;
};

// surrender
if (_dikCode in actionKeys "Surrender") then {
  
    _vehicle = vehicle player;
    _inVehicle = (_vehicle != player);
    _onLadder =    (getNumber (configFile >> "CfgMovesMaleSdr" >> "States" >> (animationState player) >> "onLadder")) == 1;
    _canDo = (!r_drag_sqf and !r_player_unconscious and !_onLadder and !_inVehicle);
  
    if (_canDo and !DZE_Surrender and !(player isKindOf  "PZombie_VB")) then {
        DZE_Surrender = true;
        _dropPrimary = false;
        _dropSecondary = false;

        _primaryWeapon = primaryWeapon player;
        if (_primaryWeapon != "") then {_dropPrimary = true;};
        _secondaryWeapon = "";
        {
            if ((getNumber (configFile >> "CfgWeapons" >> _x >> "Type")) == 2) exitWith {
                    _secondaryWeapon = _x;
            };
        } forEach (weapons player);
        if (_secondaryWeapon != "") then {_dropSecondary = true;};

        if (_dropPrimary or _dropSecondary) then {
            player playActionNow "PutDown";
            _iPos = getPosATL player;
            _radius = 1;
            _item = createVehicle ["WeaponHolder", _iPos, [], _radius, "CAN_COLLIDE"];
            _item setposATL _iPos;
            if (_dropPrimary) then {
                _iItem = _primaryWeapon;
                _removed = ([player,_iItem,1] call BIS_fnc_invRemove);
                if (_removed == 1) then {
                    _item addWeaponCargoGlobal [_iItem,1];
                };
            };
            if (_dropSecondary) then {
                _iItem = _secondaryWeapon;
                _removed = ([player,_iItem,1] call BIS_fnc_invRemove);
                if (_removed == 1) then {
                    _item addWeaponCargoGlobal [_iItem,1];
                };
            };
            player reveal _item;
        };

        // set publicvariable that allows other player to access gear
        player setVariable ["DZE_Surrendered", true, true];
        // surrender animation
        player playMove "AmovPercMstpSsurWnonDnon";
    };
    _handled = true;
};

if (_dikCode in actionKeys "MoveForward") exitWith {r_interrupt = true; if (DZE_Surrender) then {call dze_surrender_off};};
if (_dikCode in actionKeys "MoveLeft") exitWith {r_interrupt = true; if (DZE_Surrender) then {call dze_surrender_off};};
if (_dikCode in actionKeys "MoveRight") exitWith {r_interrupt = true; if (DZE_Surrender) then {call dze_surrender_off};};
if (_dikCode in actionKeys "MoveBack") exitWith {r_interrupt = true; if (DZE_Surrender) then {call dze_surrender_off};};

//Prevent exploit of drag body
if ((_dikCode in actionKeys "Prone") and r_drag_sqf) exitWith { force_dropBody = true; };
if ((_dikCode in actionKeys "Crouch") and r_drag_sqf) exitWith { force_dropBody = true; };

_shift =     _this select 2;
_ctrl =     _this select 3;
_alt =        _this select 4;

//diag_log format["Keypress: %1", _this];
if ((_dikCode in actionKeys "Gear") and (vehicle player != player) and !_shift and !_ctrl and !_alt && !dialog) then {
            createGearDialog [player, "RscDisplayGear"];
            _handled = true;
};

if (_dikCode in (actionKeys "GetOver")) then {
  
    if (player isKindOf  "PZombie_VB") then {
        _handled = true;
        DZE_PZATTACK = true;
    } else {
        _nearbyObjects = nearestObjects[getPosATL player, dayz_disallowedVault, 8];
        if (count _nearbyObjects > 0) then {
            if((diag_tickTime - dayz_lastCheckBit > 4)) then {
                [objNull, player, rSwitchMove,"GetOver"] call RE;
                player playActionNow "GetOver";
                dayz_lastCheckBit = diag_tickTime;
            } else {
                _handled = true;
            };
        };
    };
};
//if (_dikCode == 57) then {_handled = true}; // space
//if (_dikCode in actionKeys 'MoveForward' or _dikCode in actionKeys 'MoveBack') then {r_interrupt = true};
if (_dikCode == 210) then {
        _nill = execvm "\z\addons\dayz_code\actions\playerstats.sqf";
};

if (_dikCode in actionKeys "ForceCommandingMode") then {_handled = true};
if (_dikCode in actionKeys "PushToTalk" and (diag_tickTime - dayz_lastCheckBit > 10)) then {
    dayz_lastCheckBit = diag_tickTime;
    [player,50,true,(getPosATL player)] spawn player_alertZombies;
};
if (_dikCode in actionKeys "VoiceOverNet" and (diag_tickTime - dayz_lastCheckBit > 10)) then {
    dayz_lastCheckBit = diag_tickTime;
    [player,50,true,(getPosATL player)] spawn player_alertZombies;
};
if (_dikCode in actionKeys "PushToTalkDirect" and (diag_tickTime - dayz_lastCheckBit > 10)) then {
    dayz_lastCheckBit = diag_tickTime;
    [player,15,false,(getPosATL player)] spawn player_alertZombies;
};
if (_dikCode in actionKeys "Chat" and (diag_tickTime - dayz_lastCheckBit > 10)) then {
    dayz_lastCheckBit = diag_tickTime;
    [player,15,false,(getPosATL player)] spawn player_alertZombies;
};
if (_dikCode in actionKeys "User20" and (diag_tickTime - dayz_lastCheckBit > 5)) then {
    dayz_lastCheckBit = diag_tickTime;
    _nill = execvm "\z\addons\dayz_code\actions\playerstats.sqf";
};

// numpad 8 0x48 now pgup 0xC9 1
if ((_dikCode == 0xC9 and (!_alt or !_ctrl)) or (_dikCode in actionKeys "User15")) then {
    DZE_Q = true;
};
// numpad 2 0x50 now pgdn 0xD1
if ((_dikCode == 0xD1 and (!_alt or !_ctrl)) or (_dikCode in actionKeys "User16")) then {
    DZE_Z = true;
};


// numpad 8 0x48 now pgup 0xC9 0.1
if ((_dikCode == 0xC9 and (_alt and !_ctrl)) or (_dikCode in actionKeys "User13")) then {
    DZE_Q_alt = true;
};
// numpad 2 0x50 now pgdn 0xD1
if ((_dikCode == 0xD1 and (_alt and !_ctrl)) or (_dikCode in actionKeys "User14")) then {
    DZE_Z_alt = true;
};


// numpad 8 0x48 now pgup 0xC9 0.01
if ((_dikCode == 0xC9 and (!_alt and _ctrl)) or (_dikCode in actionKeys "User7")) then {
    DZE_Q_ctrl = true;
};
// numpad 2 0x50 now pgdn 0xD1
if ((_dikCode == 0xD1 and (!_alt and _ctrl)) or (_dikCode in actionKeys "User8")) then {
    DZE_Z_ctrl = true;
};




// numpad 4 0x4B now Q 0x10
if (_dikCode == 0x10 or (_dikCode in actionKeys "User17")) then {
    DZE_4 = true;
};      
// numpad 6 0x4D now E 0x12
if (_dikCode == 0x12 or (_dikCode in actionKeys "User18")) then {
    DZE_6 = true;
};
// numpad 5 0x4C now space 0x39
if (_dikCode == 0x39 or (_dikCode in actionKeys "User19")) then {
    DZE_5 = true;
};

if (_dikCode == 0x44 ) then {
    if (debugmonitor) then {
        debugmonitor = false;
        hintsilent "";
        }
    else {
        [] execVM "Scripts\Debug Monitor\custom_monitor.sqf";
        };

};

if (_dikCode == 0x43) then {
    debugmonitor = false;
    hintsilent "";
    _helpdlg = createdialog "HELP_DIALOG";
};

_handled
 
You must log in or register to reply here.
Back
Top